Re: Connectivity Query !

Stu Barton (stu@spadecl.demon.co.uk)
Thu, 29 May 1997 18:09:29 +0100

Here you go.. Stephen -- any problems e-mail me..

1. Make a directory c:\omni
2. Make a directory c:\omni\backup
3. cut and paste into a file called omniback.bat the text below, between
the lines of ****
4. move this file, omniback.bat, into the c:\omni directory
5. copy omnicom.exe to the same directory c:\omni
6. Things you may have to change.....
1) line 'set OCTTY=2,19200 ----- 2 is the PC com port that you connect
the cable in, 19200 is the speed, this has to be the same as you set on the
Omni.
2) The lines set FILES1= to set FILES4= these are the files you
are going to backup.
NOTE any files you create on the omni in the database,spreadsheet etc can
be added to the line set FILES4=
I have added one to set FILES3= which is BIRTHDAY.GDB ((YOU WILL HAVE TO
DELETE THIS.)) Unless ofcourse you have a database file called birthday....
7. Connect serial cable PC - Omni
8. Change directory to c:\omni and run omniback.bat there is a prompt when
ready to connect.
****************************************************************************
**************************
@echo off
Pause Please Make Sure The OmniGo is set to Baud Rate Of 19200
REM **** The next line sets the Com port and the transfer speed *****
set OCTTY=2,19200
set SCRIPTFILE=backup.ocs
if exist %SCRIPTFILE% del %SCRIPTFILE%
set FILES1=PERSONAL.000 FINANCE.FDB JOTTER.000 JWTIME.WDB MASTER.MDB
set FILES2=NOTEPAD.NDB PHONE.PDB APPT.ADB TIMESHEE.000
set FILES3=BOOK_REA.000 EXPENSE_.000 WTROMDB.000 BIRTHDAY.GDB
set FILES4=
echo SD B:>>%SCRIPTFILE%
echo SD \GEOWORKS\DOCUMENT>>%SCRIPTFILE%
for %%F in (%FILES1%) do echo GET %%F>>%SCRIPTFILE%
for %%F in (%FILES2%) do echo GET %%F>>%SCRIPTFILE%
for %%F in (%FILES3%) do echo GET %%F>>%SCRIPTFILE%
for %%F in (%FILES4%) do echo GET %%F>>%SCRIPTFILE%
echo QUIT>>%SCRIPTFILE%
cd backup
for %%F in (1 2 3 4 5) do if not exist %%F\nul md %%F
deltree /y 5\*.*
copy 4\*.* 5
deltree /y 4\*.*
copy 3\*.* 4
deltree /y 3\*.*
copy 2\*.* 3
deltree /y 2\*.*
copy 1\*.* 2
deltree /y 1\*.*
copy *.* 1
echo Make sure the Omnigo is ready to connect.
pause
..\omnicom<..\%SCRIPTFILE%
cd ..
****************************************************************************
***************************

--
========================================
               stu@spadecl.demon.co.uk
========================================

> Stephen J. Hall <stephenjhall@geocities.com> > Subject: Connectivity Query ! > Date: 28 May 1997 23:16

WROTE

> Hi folks, > I do not have the connectivity pack but I do have the HP Serial Cable > which I use regularly to back up the files onto my PC using Omnicom. > > Whilst browsing the net I discovered a Batch file which uses DOS > Re-Direction to execute a series of Put's to backup a whole list of > files without the need to type Put's everytime. > I have made many attempts to get this batch file to work but something > is very wrong. I must admit I am not very familiar with DOS > Re-direction. > > Can Anyone help ?